Practice Problems and Solutions 2 B Alternate

These problems are offered to help understand the lecture material and assist with completing homeworks; they will also form the basis for some problems on the midterms. They are entirely optional, and feel free to skip if you understand a concept!

You should do these problems on paper or mentally first, and only THEN check the solution.

This set of problems uses the built-in Haskell notations for tuples and lists; for a version of the same problems using BB Haskell, with explicit definitions for Pairs and Lists see here.

2. BareBones Haskell: Polymorphic Types and Type Checking

Suppose we have the following data declarations:

data Either a b = Left a | Right b 
data Maybe a = Nothing | Just a 


 

We assume that we can have Integer and Bools as defined in the Haskell Prelude. Assume for the purposes of these exercises that all arithmetic operators operate only on Integers, so pretend the type of (+) is:

 (+): Integer -> Integer -> Integer.

Give the type of the following (polymorphic) functions. Note: Assume that any numeric type is simply Integer. Also, use type variables starting with a, b, c, etc. There are no errors in these functions, all can be given a polymorphic type.

2.1.

id x = x

Show Solution

id :: a -> a

2.2.

select x y = x

Show Solution

select :: a -> b -> a

2.3.

makePair x y = (x, y)

Show Solution

makePair :: a -> b -> (a, b)

2.4.

makeSingleton x = [x]

Show Solution

makeSingleton :: a -> [a]

2.5.

two x = (x, x)

Show Solution

two :: a -> (a, a)

2.6.

triple2Pair (x, y, z) = (x, (y, z))

Show Solution

triple2Pair :: (a,b,c) -> (a,(b,c))

2.7.

pair2List (x, y) = [x,y]

Show Solution

pair2List :: (a,a) -> [a]

2.8.

list2Pairs [w,x,y,z] = ((w,x),(y,z))

Show Solution

list2Pairs :: [a] -> ((a,a),(a,a))

2.9.

safeSecond (_:x:_) = Just x
safeSecond _       = Nothing

Show Solution

safeSecond :: [a] -> Maybe a

2.10.

checkedSecond (_:x:_) = Right x
checkedSecond _       = Left "Error: Empty List"

Show Solution

checkedSecond :: [b] -> Either [Char] b

2.11.

weirdSecond (_:x:_) = Right (Just x)
weirdSecond _       = Left Nothing

Show Solution

weirdSecond :: [a] -> Either (Maybe b) (Maybe a)

2.12.

strangeSecond (_:x:_) = Just (Right x)
strangeSecond _       = Nothing

Show Solution

strangeSecond :: [a] -> Maybe (Either b a)

2.13.

bizarreHead []           = Nothing
bizarreHead ((Just x):_) = Just (Just x)

Show Solution

bizarreHead :: [(Maybe a)] -> Maybe (Maybe a)

2.14.

repeat1 x 0 = []
repeat1 x n = x : (repeat1 x (n-1))

Show Solution

repeat1 :: a -> Integer -> [a]

2.15.

repeat2 x y 0 = []
repeat2 x y n = (x:y:(repeat2 x y (n-1)))

Show Solution

repeat2 :: a -> a -> Integer -> [a]

2.16.

repeatPairs x y 0 = []
repeatPairs x y n = ((x, y) : (repeatPairs x y (n-1)))

Show Solution

repeatPairs :: a -> b -> Integer -> [(a, b)]

2.17.

try1 (x, y) z = (x, (y, z))

Show Solution

try1 :: (a, b)-> c -> (a, (b, c))

2.18.

try2 (x, y, z) = (x, (y z))

Show Solution

try2 :: (a, (b -> c), b) -> (a, c)

2.19.

try3 x y =  x ( (<4) y )

Show Solution

try3 :: (Bool -> a) -> Integer -> a

2.20.

try4 x y z = x ((*3) y) ((`mod` z) 2)

Show Solution

try4 :: (Integer -> Integer -> a) -> Integer -> Integer -> a

2.21.

apply1 x y = x y

Show Solution

apply1 :: (a -> b) -> a -> b

2.22.

apply2 x y = x (x y)

Show Solution

apply2 :: (a -> a) -> a -> a

2.23.

apply3 x y z = (x y) z

Show Solution

apply3 :: (a -> b -> c) -> a -> b -> c

2.24.

apply4 x y z = x (y z)

Show Solution

apply4 :: (a -> b) -> (c -> a) -> c -> b

2.25.

apply5 x y z = x y z

Show Solution

apply5 :: (a -> b -> c) -> a -> b -> c

2.26.

apply6 x y z = (x z) (y z)

Show Solution

apply6 :: (a -> b -> c) -> (a -> b) -> a -> c

2.27.

apply7 w x y z = w (x (y z))

Show Solution

apply7 :: (a -> b) -> (c -> a) -> (d -> c) -> d -> b

2.28.

apply8 w x y z = ((w x) y) z

Show Solution

apply8 :: (a -> b -> c -> d) -> a -> b -> c -> d

2.29.

apply9 w x y z = w x y z

Show Solution

apply9 :: (a -> b -> c -> d) -> a -> b -> c -> d

2.30.

switch1 x y = switch1 y x    -- will not terminate, but will type check!

Show Solution

switch1 :: a -> a -> b

2.31.

switch2 x y z = switch2 y x z

Show Solution

switch2 :: a -> a -> b -> c

2.32.

switch3 x y z = switch3 z y x

Show Solution

switch3 :: a -> b -> a -> c

2.33.

switch4 x y z = switch4 z x y

Show Solution

switch4 :: a -> a -> a -> b

2.34.

lam1 = \x -> x

Show Solution

lam1 :: a -> a

2.35.

lam2 = \x -> (x, x)

Show Solution

lam2 :: a -> (a, a)

2.36.

lam3 = \x -> (x, 4, x)

Show Solution

lam3 :: a -> (a, Integer, a)

2.37.

lam4 = \_ -> Nothing    -- You can use an anonymous variable in lambda expression!

Show Solution

lam4 :: a -> Maybe b

2.38.

lam5 = \x -> ((Left x), (Just x))

Show Solution

lam5 :: a -> (Either a b, Maybe a)

2.39.

lam6 = \x y -> y x

Show Solution

lam6 :: a -> (a -> b) -> b

2.40.

lam7 = \x -> \y -> y x

Show Solution

lam7 :: a -> (a -> b) -> b

2.41.

lam8 = \x -> \y -> f x y
          where f x = \x y -> (x, x)

Show Solution

lam8 :: a -> b -> c -> (b, b)

2.42.

lam9 x = (\y -> x y)

Show Solution

lam9 :: (a -> b) -> a -> b

2.43.

lam10 x y = (\z -> x (y, z))

Show Solution

lam10 :: ((a, b) -> c) -> a -> b -> c

2.44.

test1 = \x y -> ((\z -> x z) y)

Show Solution

test1 :: (a -> b) -> a -> b

2.45.

test2 x = \y -> ((\z -> x z) y)

Show Solution

test2 :: (a -> b) -> a -> b

2.46.

test3 x y =  (x . y) 5

Show Solution

test3 :: (b -> c) -> (Integer -> b) -> c

2.47.

test4 x y = ( (*3) . x) y

Show Solution

test4 :: (a -> Integer) -> a -> Integer

2.48.

test5 x y = (x . (*3)) y

Show Solution

test5 :: (Integer -> a) -> Integer -> a

2.49.

test6 = \x -> ((\y z -> y z) x 3)

Show Solution

test6 :: (Integer -> a) -> a

2.50.

test7 x y = x . (`f` True)
              where f x y = (x, y)

Show Solution

test7 :: ((a, Bool) -> b) -> c -> a -> b

End of Practice Problems 2 B.